1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
|
#include "abi.inc"
#include "defs.inc"
#define JBUF -72
.text
FUNC cepis__js_ws
.Lws_loop:
movzbl (%rdi), %eax
cmp $' ', %al
je .Lws_adv
cmp $9, %al
jb .Lws_end
cmp $13, %al
jbe .Lws_adv
.Lws_end:
mov %rdi, %rax
ret
.Lws_adv:
inc %rdi
jmp .Lws_loop
ENDFUNC cepis__js_ws
FUNC cepis__js_hex4
xor %ecx, %ecx
mov $4, %r8d
.Lhex_loop:
movzbl (%rdi), %eax
inc %rdi
cmp $'0', %al
jb .Lhex_bad
cmp $'9', %al
jbe .Lhex_digit
or $0x20, %al
cmp $'a', %al
jb .Lhex_bad
cmp $'f', %al
ja .Lhex_bad
sub $('a' - 10), %eax
jmp .Lhex_acc
.Lhex_digit:
sub $'0', %eax
.Lhex_acc:
shl $4, %ecx
or %eax, %ecx
dec %r8d
jnz .Lhex_loop
mov %ecx, %eax
ret
.Lhex_bad:
mov $-1, %eax
ret
ENDFUNC cepis__js_hex4
FUNC cepis__js_raw_string
cmpb $'"', (%rdi)
jne .Lraw_bad
inc %rdi
.Lraw_loop:
movzbl (%rdi), %eax
test %al, %al
jz .Lraw_bad
cmp $'\\', %al
je .Lraw_esc
cmp $'"', %al
je .Lraw_close
inc %rdi
jmp .Lraw_loop
.Lraw_esc:
cmpb $0, 1(%rdi)
je .Lraw_bad
add $2, %rdi
jmp .Lraw_loop
.Lraw_close:
lea 1(%rdi), %rax
ret
.Lraw_bad:
xor %eax, %eax
ret
ENDFUNC cepis__js_raw_string
FUNC cepis__js_skip
PROLOGUE 8
call cepis__js_ws
mov %rax, %rbx
movzbl (%rbx), %eax
test %al, %al
jz .Lskip_bad
cmp $'"', %al
je .Lskip_str
cmp $'{', %al
je .Lskip_nest
cmp $'[', %al
je .Lskip_nest
jmp .Lskip_token
.Lskip_str:
mov %rbx, %rdi
call cepis__js_raw_string
EPILOGUE
ret
.Lskip_token:
mov %rbx, %r12
.Lskip_token_loop:
movzbl (%r12), %eax
cmp $'0', %al
jb .Lskip_token_sym
cmp $'9', %al
jbe .Lskip_token_adv
or $0x20, %al
cmp $'a', %al
jb .Lskip_token_end
cmp $'z', %al
jbe .Lskip_token_adv
jmp .Lskip_token_end
.Lskip_token_sym:
cmp $'+', %al
je .Lskip_token_adv
cmp $'-', %al
je .Lskip_token_adv
cmp $'.', %al
je .Lskip_token_adv
jmp .Lskip_token_end
.Lskip_token_adv:
inc %r12
jmp .Lskip_token_loop
.Lskip_token_end:
cmp %rbx, %r12
je .Lskip_bad
mov %r12, %rax
EPILOGUE
ret
.Lskip_nest:
xor %r13d, %r13d
.Lskip_nest_loop:
movzbl (%rbx), %eax
test %al, %al
jz .Lskip_bad
cmp $'"', %al
je .Lskip_nest_str
cmp $'{', %al
je .Lskip_nest_open
cmp $'[', %al
je .Lskip_nest_open
cmp $'}', %al
je .Lskip_nest_close
cmp $']', %al
je .Lskip_nest_close
inc %rbx
jmp .Lskip_nest_loop
.Lskip_nest_str:
mov %rbx, %rdi
call cepis__js_raw_string
test %rax, %rax
jz .Lskip_bad
mov %rax, %rbx
jmp .Lskip_nest_loop
.Lskip_nest_open:
inc %r13d
inc %rbx
jmp .Lskip_nest_loop
.Lskip_nest_close:
dec %r13d
inc %rbx
test %r13d, %r13d
jz .Lskip_nest_done
jmp .Lskip_nest_loop
.Lskip_nest_done:
mov %rbx, %rax
EPILOGUE
ret
.Lskip_bad:
xor %eax, %eax
EPILOGUE
ret
ENDFUNC cepis__js_skip
FUNC cepis__js_string
PROLOGUE 40
mov %rsi, %r14
movq $0, JBUF(%rbp)
movq $0, JBUF+8(%rbp)
movq $0, JBUF+16(%rbp)
movq $0, (%r14)
cmpb $'"', (%rdi)
jne .Lstr_fail
lea 1(%rdi), %rbx
.Lstr_loop:
movzbl (%rbx), %eax
test %al, %al
jz .Lstr_fail
cmp $'"', %al
je .Lstr_done
cmp $'\\', %al
je .Lstr_esc
lea JBUF(%rbp), %rdi
movzbl (%rbx), %esi
call cepis__buf_appendc
test %eax, %eax
jnz .Lstr_fail
inc %rbx
jmp .Lstr_loop
.Lstr_esc:
movzbl 1(%rbx), %eax
test %al, %al
jz .Lstr_fail
cmp $'u', %al
je .Lstr_uesc
mov %eax, %r12d
cmp $'"', %al
je .Lstr_emit
cmp $'\\', %al
je .Lstr_emit
cmp $'/', %al
je .Lstr_emit
cmp $'b', %al
je .Lstr_bs
cmp $'f', %al
je .Lstr_ff
cmp $'n', %al
je .Lstr_nl
cmp $'r', %al
je .Lstr_cr
cmp $'t', %al
je .Lstr_tab
jmp .Lstr_fail
.Lstr_bs:
mov $8, %r12d
jmp .Lstr_emit
.Lstr_ff:
mov $12, %r12d
jmp .Lstr_emit
.Lstr_nl:
mov $10, %r12d
jmp .Lstr_emit
.Lstr_cr:
mov $13, %r12d
jmp .Lstr_emit
.Lstr_tab:
mov $9, %r12d
.Lstr_emit:
lea JBUF(%rbp), %rdi
mov %r12d, %esi
call cepis__buf_appendc
test %eax, %eax
jnz .Lstr_fail
add $2, %rbx
jmp .Lstr_loop
.Lstr_uesc:
lea 2(%rbx), %rdi
call cepis__js_hex4
test %eax, %eax
js .Lstr_fail
mov %eax, %r12d
add $6, %rbx
cmp $0xD800, %r12d
jb .Lstr_encode
cmp $0xDBFF, %r12d
ja .Lstr_low
cmpb $'\\', (%rbx)
jne .Lstr_repl
cmpb $'u', 1(%rbx)
jne .Lstr_repl
lea 2(%rbx), %rdi
call cepis__js_hex4
test %eax, %eax
js .Lstr_repl
mov %eax, %r13d
cmp $0xDC00, %r13d
jb .Lstr_repl
cmp $0xDFFF, %r13d
ja .Lstr_repl
add $6, %rbx
sub $0xD800, %r12d
shl $10, %r12d
sub $0xDC00, %r13d
add %r13d, %r12d
add $0x10000, %r12d
jmp .Lstr_encode
.Lstr_low:
cmp $0xDFFF, %r12d
ja .Lstr_encode
.Lstr_repl:
mov $0xFFFD, %r12d
.Lstr_encode:
cmp $0x80, %r12d
jb .Lstr_enc1
cmp $0x800, %r12d
jb .Lstr_enc2
cmp $0x10000, %r12d
jb .Lstr_enc3
mov %r12d, %esi
shr $18, %esi
or $0xF0, %esi
lea JBUF(%rbp), %rdi
call cepis__buf_appendc
test %eax, %eax
jnz .Lstr_fail
mov %r12d, %esi
shr $12, %esi
and $0x3F, %esi
or $0x80, %esi
lea JBUF(%rbp), %rdi
call cepis__buf_appendc
test %eax, %eax
jnz .Lstr_fail
jmp .Lstr_enc_tail2
.Lstr_enc3:
mov %r12d, %esi
shr $12, %esi
or $0xE0, %esi
lea JBUF(%rbp), %rdi
call cepis__buf_appendc
test %eax, %eax
jnz .Lstr_fail
.Lstr_enc_tail2:
mov %r12d, %esi
shr $6, %esi
and $0x3F, %esi
or $0x80, %esi
lea JBUF(%rbp), %rdi
call cepis__buf_appendc
test %eax, %eax
jnz .Lstr_fail
jmp .Lstr_enc_tail1
.Lstr_enc2:
mov %r12d, %esi
shr $6, %esi
or $0xC0, %esi
lea JBUF(%rbp), %rdi
call cepis__buf_appendc
test %eax, %eax
jnz .Lstr_fail
.Lstr_enc_tail1:
mov %r12d, %esi
and $0x3F, %esi
or $0x80, %esi
lea JBUF(%rbp), %rdi
call cepis__buf_appendc
test %eax, %eax
jnz .Lstr_fail
jmp .Lstr_loop
.Lstr_enc1:
mov %r12d, %esi
lea JBUF(%rbp), %rdi
call cepis__buf_appendc
test %eax, %eax
jnz .Lstr_fail
jmp .Lstr_loop
.Lstr_done:
inc %rbx
cmpq $0, JBUF(%rbp)
jne .Lstr_take
call cepis__empty
test %rax, %rax
jz .Lstr_fail
mov %rax, (%r14)
mov %rbx, %rax
EPILOGUE
ret
.Lstr_take:
lea JBUF(%rbp), %rdi
call cepis__buf_take
mov %rax, (%r14)
mov %rbx, %rax
EPILOGUE
ret
.Lstr_fail:
lea JBUF(%rbp), %rdi
call cepis__buf_free
movq $0, (%r14)
xor %eax, %eax
EPILOGUE
ret
ENDFUNC cepis__js_string
FUNC cepis__js_scalar_text
PROLOGUE 24
mov %rsi, %r14
movq $0, (%r14)
call cepis__js_ws
mov %rax, %rbx
movzbl (%rbx), %eax
cmp $'"', %al
je .Lsc_string
cmp $'{', %al
je .Lsc_fail
cmp $'[', %al
je .Lsc_fail
mov %rbx, %rdi
call cepis__js_skip
test %rax, %rax
jz .Lsc_fail
mov %rax, %r12
mov %r12, %r13
sub %rbx, %r13
cmp $4, %r13
jne .Lsc_copy
mov %rbx, %rdi
lea .Lsc_null(%rip), %rsi
mov $4, %rdx
call memcmp@PLT
test %eax, %eax
jnz .Lsc_copy
call cepis__empty
test %rax, %rax
jz .Lsc_fail
mov %rax, (%r14)
mov %r12, %rax
EPILOGUE
ret
.Lsc_copy:
mov %rbx, %rdi
mov %r13, %rsi
call cepis__strndup
test %rax, %rax
jz .Lsc_fail
mov %rax, (%r14)
mov %r12, %rax
EPILOGUE
ret
.Lsc_string:
mov %rbx, %rdi
mov %r14, %rsi
call cepis__js_string
EPILOGUE
ret
.Lsc_fail:
xor %eax, %eax
EPILOGUE
ret
ENDFUNC cepis__js_scalar_text
FUNC cepis__js_number
PROLOGUE 40
mov %rsi, %r14
call cepis__js_ws
mov %rax, %rbx
cmpb $'"', (%rbx)
je .Lnum_quoted
mov %rbx, %rdi
lea LOCAL0(%rbp), %rsi
call strtod@PLT
mov LOCAL0(%rbp), %rax
cmp %rbx, %rax
je .Lnum_fail
movsd %xmm0, (%r14)
EPILOGUE
ret
.Lnum_quoted:
mov %rbx, %rdi
lea LOCAL1(%rbp), %rsi
call cepis__js_string
test %rax, %rax
jz .Lnum_fail
mov %rax, %r12
mov LOCAL1(%rbp), %rdi
lea LOCAL0(%rbp), %rsi
call strtod@PLT
movsd %xmm0, LOCAL2(%rbp)
mov LOCAL1(%rbp), %rbx
mov LOCAL0(%rbp), %r13
mov %rbx, %rdi
call free@PLT
cmp %rbx, %r13
je .Lnum_fail
movsd LOCAL2(%rbp), %xmm0
movsd %xmm0, (%r14)
mov %r12, %rax
EPILOGUE
ret
.Lnum_fail:
xor %eax, %eax
EPILOGUE
ret
ENDFUNC cepis__js_number
.section .rodata
.Lsc_null:
.ascii "null"
.section .note.GNU-stack,"",@progbits
|